web-dev-qa-db-fra.com

Comment enregistrer des objets sur une console avec AppleScript

J'essaie simplement d'enregistrer l'état des objets tout au long de la vie de mon AppleScript. Dans d'autres langages, les méthodes toString () de l'objet rendront le texte équivalent et je peux les utiliser. Dans AppleScript, cela ne semble pas être le cas.

convert applescript object to string (similar to toString)

Sortira l'objet Finder (et ses propriétés) dans la fenêtre "Résultats" de l'éditeur AppleScript, mais uniquement si c'est la dernière instruction qui est exécutée.

Si j'ai une instruction trace () (qui prend un message à des fins de journalisation):

on trace(message)
do Shell script "cat >>~/log/applescript.txt <<END_OF_THE_LOG
" & (message as text) & "
END_OF_THE_LOG"
end trace

et essayez d'enregistrer le même objet, je reçois

Can’t make properties of application "Finder" into type text.

Je suis ouvert à de meilleures façons de se connecter à une console, mais j'aimerais savoir comment écrire les propriétés d'un objet (comme le fait AppleScript Editor) au milieu d'un script pour tester l'une ou l'autre façon.

applescript
47
umop

Utilisez simplement l'instruction log dans l'éditeur AppleScript. Lorsque vous affichez les résultats dans Applescript Editor, en bas de la fenêtre, appuyez sur le bouton "Événements". Normalement, le bouton "Résultats" est enfoncé et vous ne voyez que le résultat de la dernière instruction comme vous le mentionnez. Changez donc le bouton en "Evénements". Cela vous montrera tout ce qui se passe pendant l'exécution du script, ainsi que toutes les instructions log que vous placez également dans le code. Notez que les instructions log ne doivent pas nécessairement être du texte. Vous pouvez enregistrer n'importe quel objet.

C'est le meilleur moyen de déboguer votre script et de voir ce qui se passe. Par exemple, essayez ceci et regardez les "événements". En réalité, vous pensiez que vous n'avez pas besoin de beaucoup d'instructions log si vous affichez les événements car tout est déjà enregistré!

set someFolder to path to desktop
log someFolder

tell application "Finder"
    set someItem to first item of someFolder
    log someItem

    set itemProps to properties of someItem
    log itemProps
end tell
34
regulus6633

AppleScript ne facilite pas les choses:

  • log uniquement journaux lors de l'exécution dans AppleScript Editor ou lors de l'exécution via osascript (vers stderr dans ce cas) - la sortie sera perdue dans d'autres cas, comme lorsque les applications exécutent un script avec la classe Cocoa NSAppleScript.

  • log accepte uniquement un argument; bien qu'il accepte n'importe quel type d'objet, il n'est pas facile d'obtenir une représentation significative des types non intégrés: essayez log me pour obtenir des informations sur le script lui-même, par exemple; fréquemment, log (get properties of <someObj>) doit être utilisé pour obtenir des informations significatives; notez la syntaxe encombrante, qui est requise, car le simple fait d'utiliser log properties of <someObj> affiche simplement le nom du formulaire de référence au lieu des propriétés qu'il pointe vers (par exemple, log properties of me ne génère inutilement que (*properties*)).

  • En général, AppleScript rend très difficile l'obtention de représentations textuelles significatives d'objets de types non intégrés: <someObj> as text (Identique à: <someObj> as string) Énervant breaks - lance une erreur d'exécution - pour de tels objets; essayez me as text.

Vous trouverez ci-dessous sous-programmes d'assistance qui résolvent ces problèmes:

  • dlog() est un sous-programme qui combine la dérivation de représentations textuelles significatives de tous les objets avec la possibilité d'écrire sur plusieurs cibles de journal (y compris syslog et fichiers) sur la base d'une variable de configuration globale.
  • toString() (effectivement intégré dans dlog()) est un sous-programme qui prend un seul objet de n'importe quel type et en dérive une représentation textuelle significative.

Pointe du chapeau à 1,61803; sa réponse a fourni des indications pour la mise en œuvre des différentes cibles de journalisation.

Exemples:

  # Setup: Log to syslog and a file in the home dir.
  #        Other targets supported: "log", "alert"
  #        Set to {} to suppress logging.
set DLOG_TARGETS to { "syslog", "~/as.log" } 
  # Log properties of the front window of frontmost application.
dlog(front window of application (path to frontmost application as text))
  # Log properties of own front window; note the *list* syntax for multiple args.
dlog({"my front window: ", front window})

  # Get properties of the running script as string.
toString(me) # ->, e.g.: [script name="sandbox"] {selection:insertion point after character 2475 of text of document "sandbox2.scpt", frontmost:true, class:application, name:"AppleScript Editor", version:"2.6"}

Voir les commentaires du code source au-dessus de chaque sous-routine pour plus de détails.

code source dlog ()

    # Logs a text representation of the specified object or objects, which may be of any type, typically for debugging.
    # Works hard to find a meaningful text representation of each object.
    # SYNOPSIS
    #   dlog(anyObjOrListOfObjects)
    # USE EXAMPLES
    #   dlog("before")  # single object
    #     dlog({ "front window: ", front window }) # list of objects
    # SETUP
    #   At the top of your script, define global variable DLOG_TARGETS and set it to a *list* of targets (even if you only have 1 target).
    #     set DLOG_TARGETS to {} # must be a list with any combination of: "log", "syslog", "alert", <posixFilePath>
    #   An *empty* list means that logging should be *disabled*.
    #   If you specify a POSIX file path, the file will be *appended* to; variable references in the path
    #   are allowed, and as a courtesy the path may start with "~" to refer to your home dir.
    #   Caveat: while you can *remove* the variable definition to disable logging, you'll take an additional performance hit.
    # SETUP EXAMPLES
    #    For instance, to use both AppleScript's log command *and* display a GUI alert, use:
    #       set DLOG_TARGETS to { "log", "alert" }
    # Note: 
    #   - Since the subroutine is still called even when DLOG_TARGETS is an empty list, 
    #     you pay a performancy penalty for leaving dlog() calls in your code.
    #   - Unlike with the built-in log() method, you MUST use parentheses around the parameter.
    #   - To specify more than one object, pass a *list*. Note that while you could try to synthesize a single
    #     output string by concatenation yourself, you'd lose the benefit of this subroutine's ability to derive
    #     readable text representations even of objects that can't simply be converted with `as text`.
    on dlog(anyObjOrListOfObjects)
        global DLOG_TARGETS
        try
            if length of DLOG_TARGETS is 0 then return
        on error
            return
        end try
        # The following tries hard to derive a readable representation from the input object(s).
        if class of anyObjOrListOfObjects is not list then set anyObjOrListOfObjects to {anyObjOrListOfObjects}
        local lst, i, txt, errMsg, orgTids, oName, oId, prefix, logTarget, txtCombined, prefixTime, prefixDateTime
        set lst to {}
        repeat with anyObj in anyObjOrListOfObjects
            set txt to ""
            repeat with i from 1 to 2
                try
                    if i is 1 then
                        if class of anyObj is list then
                            set {orgTids, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {", "}} # '
                            set txt to ("{" & anyObj as string) & "}"
                            set AppleScript's text item delimiters to orgTids # '
                        else
                            set txt to anyObj as string
                        end if
                    else
                        set txt to properties of anyObj as string
                    end if
                on error errMsg
                    # Trick for records and record-*like* objects:
                    # We exploit the fact that the error message contains the desired string representation of the record, so we extract it from there. This (still) works as of AS 2.3 (OS X 10.9).
                    try
                        set txt to do Shell script "egrep -o '\\{.*\\}' <<< " & quoted form of errMsg
                    end try
                end try
                if txt is not "" then exit repeat
            end repeat
            set prefix to ""
            if class of anyObj is not in {text, integer, real, boolean, date, list, record} and anyObj is not missing value then
                set prefix to "[" & class of anyObj
                set oName to ""
                set oId to ""
                try
                    set oName to name of anyObj
                    if oName is not missing value then set prefix to prefix & " name=\"" & oName & "\""
                end try
                try
                    set oId to id of anyObj
                    if oId is not missing value then set prefix to prefix & " id=" & oId
                end try
                set prefix to prefix & "] "
                set txt to prefix & txt
            end if
            set lst to lst & txt
        end repeat
        set {orgTids, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {" "}} # '
        set txtCombined to lst as string
        set prefixTime to "[" & time string of (current date) & "] "
        set prefixDateTime to "[" & short date string of (current date) & " " & text 2 thru -1 of prefixTime
        set AppleScript's text item delimiters to orgTids # '
        # Log the result to every target specified.
        repeat with logTarget in DLOG_TARGETS
            if contents of logTarget is "log" then
                log prefixTime & txtCombined
            else if contents of logTarget is "alert" then
                display alert prefixTime & txtCombined
            else if contents of logTarget is "syslog" then
                do Shell script "logger -t " & quoted form of ("AS: " & (name of me)) & " " & quoted form of txtCombined
            else # assumed to be a POSIX file path to *append* to.
                set fpath to contents of logTarget
                if fpath starts with "~/" then set fpath to "$HOME/" & text 3 thru -1 of fpath
                do Shell script "printf '%s\\n' " & quoted form of (prefixDateTime & txtCombined) & " >> \"" & fpath & "\""
            end if
        end repeat
    end dlog

code source toString ()

    # Converts the specified object - which may be of any type - into a string representation for logging/debugging.
    # Tries hard to find a readable representation - sadly, simple conversion with `as text` mostly doesn't work with non-primitive types.
    # An attempt is made to list the properties of non-primitive types (does not always work), and the result is prefixed with the type (class) name
    # and, if present, the object's name and ID.
    # EXAMPLE
    #       toString(path to desktop)  # -> "[alias] Macintosh HD:Users:mklement:Desktop:"
    # To test this subroutine and see the various representations, use the following:
    #   repeat with elem in {42, 3.14, "two", true, (current date), {"one", "two", "three"}, {one:1, two:"deux", three:false}, missing value, me,  path to desktop, front window of application (path to frontmost application as text)}
    #       log my toString(contents of elem)
    #   end repeat
    on toString(anyObj)
        local i, txt, errMsg, orgTids, oName, oId, prefix
        set txt to ""
        repeat with i from 1 to 2
            try
                if i is 1 then
                    if class of anyObj is list then
                        set {orgTids, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {", "}}
                        set txt to ("{" & anyObj as string) & "}"
                        set AppleScript's text item delimiters to orgTids # '
                    else
                        set txt to anyObj as string
                    end if
                else
                    set txt to properties of anyObj as string
                end if
            on error errMsg
                # Trick for records and record-*like* objects:
                # We exploit the fact that the error message contains the desired string representation of the record, so we extract it from there. This (still) works as of AS 2.3 (OS X 10.9).
                try
                    set txt to do Shell script "egrep -o '\\{.*\\}' <<< " & quoted form of errMsg
                end try
            end try
            if txt is not "" then exit repeat
        end repeat
        set prefix to ""
        if class of anyObj is not in {text, integer, real, boolean, date, list, record} and anyObj is not missing value then
            set prefix to "[" & class of anyObj
            set oName to ""
            set oId to ""
            try
                set oName to name of anyObj
                if oName is not missing value then set prefix to prefix & " name=\"" & oName & "\""
            end try
            try
                set oId to id of anyObj
                if oId is not missing value then set prefix to prefix & " id=" & oId
            end try
            set prefix to prefix & "] "
        end if
        return prefix & txt
    end toString
36
mklement0

Essayez l'une des solutions suivantes:

# echo to file
do Shell script "echo " & quoted form of (myObj as string) & ¬
    " > ~/Desktop/as_debug.txt"

# write to file
set myFile to open for access (path to desktop as text) & ¬
    "as_debug2.txt" with write permission
write myObj to myFile
close access myFile

# log to syslog
do Shell script "logger -t 'AS DEBUG' " & myObj

# show dialog
display dialog "ERROR: " & myObj

Si ce que vous essayez de consigner n'est pas du texte, vous pouvez essayer:

quoted form of (myObj as string)
10
1.61803
do Shell script "echo '" & (current date) & ": Found " & Thisfilename & "' >> ~/logs/MyGreatAppleScript.log"
1
user2548919

Voici des exemples de journal de console:

set my_int to 9945
log my_int
set my_srt to "Hamza"
log my_srt 
set my_array ["Apple","Mango","Banana","Gava"]
log my_array
set my_obj to {"ALi"} as string
log my_obj
1
M. Hamza Rajput

Similaire à toString()...

on TextOf(aVariable)
    try
        return "" & aVariable
    on error errm
        if errm begins with "Can’t make " ¬
       and errm ends with " into type Unicode text." then ¬
            return text 12 through -25 of errm
        return "item of class " & (class of aVariable) & return & errm
    end try
end TextOf
1
Gil Dawson