Quelles sont les valeurs ERRORLEVEL définies par les commandes internes cmd.exe?
ERRORLEVEL est une valeur renvoyée par la plupart des commandes cmd.exe lorsqu'elles mettent fin à ce changement en fonction d'une série de conditions, donc connaître la valeur renvoyée par les commandes est une information précieuse qui peut aider à écrire de meilleurs fichiers Batch. Tous les programmes .exe externes modifient le NIVEAU D'ERREUR à la fin (c'est un mécanisme inhérent des fonctions ExitProcess et TerminateProcess Win-32 API) et généralement ces valeurs sont documentées, mais les valeurs renvoyées par les commandes internal cmd.exe ne sont pas entièrement documentées ailleurs.
Un tableau avec des valeurs partielles ERRORLEVEL apparaît à cette question , mais uniquement pour les commandes internes qui définissent ERRORLEVEL = 0 "en cas de succès". J'ai suggéré l'OP d'une telle question pour la modifier afin d'inclure également les valeurs retournées par les "commandes non réussies", mais il a refusé et m'a invité à poster ma propre question/réponse, alors la voici! Vous devez noter qu'un NIVEAU D'ERREUR différent de zéro signifie pas signifie nécessairement que la commande a échoué! Certaines commandes se terminent sans erreur et renvoient une valeur supérieure à zéro pour indiquer un "état de sortie" différent, y compris des commandes internes (comme SET /P).
Pour mieux utiliser les commandes cmd.exe intégrées dans les fichiers Batch .bat, nous devons connaître les valeurs ERRORLEVEL qu'elles renvoient et les mécanismes impliqués dans cette gestion. La question est donc de savoir quelles commandes cmd.exe internes définissent ERRORLEVEL sur n'importe quelle valeur (y compris zéro)?
Dans cette réponse, les valeurs ERRORLEVEL renvoyées par toutes les commandes internes cmd.exe sont décrites; ils sont regroupés selon la façon dont la valeur est modifiée et présentés sous forme de tableaux de référence rapide. J'ai examiné d'autres tableaux similaires afin d'assembler celui-ci, mais j'ai rempli les valeurs manquantes via des tests effectués sur un ordinateur Windows 8.1. J'ai fait de mon mieux pour créer ces tableaux complets et précis, mais je n'avais pas testé chacune des valeurs rapportées ici, il peut donc s'agir de subtiles incohérences.
Tableau 1 - Commandes qui ne modifient pas la valeur ERRORLEVEL antérieure
BREAK
ECHO
ENDLOCAL
FOR Not change the ERRORLEVEL by itself. See "Exit Code" below.
IF Not change the ERRORLEVEL by itself.
PAUSE
RD Not change the ERRORLEVEL on errors, but the "Exit Code". See below.
REM
RMDIR Same as RD.
SET Plain SET command (no arguments). See "Table 3" below.
TITLE
Tableau 2 - Commandes qui définissent ERRORLEVEL sur 0 ou 1 selon le résultat
Command │ Set ERRORLEVEL = 0 when │ Set ERRORLEVEL = 1 when
────────┼───────────────────────────────┼─────────────────────────────────────────────────────────────
CD │Current directory was changed. │Directory not exists or is not accessible.
CHDIR │Same as CD. │
COLOR │Color was changed. │Background and foreground colors are the same.
COPY │File(s) was processed. │File not found or bad parameters given.
DATE │Date was changed or not given. │User has no admin privileges.
DEL │Almost always, excepting when: │Bad or no parameters given.
DIR │Same as COPY. │
ERASE │Same as DEL. │
MD │Directory was created. │Directory could not be created.
MKDIR │Same as MD. │
MKLINK │Link was created. │Link could not be created or bad parameters given.
MOVE │File(s) was moved/renamed. │File not found, could not be moved/renamed or bad parameters.
PUSHD │Same as CD. │+ Bad switch given.
REN │Same as MOVE. │
RENAME │Same as MOVE. │
SETLOCAL│New environment was created. │Bad parameters given.
TIME │Time was changed or not given. │User has no admin privileges.
TYPE │Same as COPY. │
VERIFY │Right or no parameters given. │Bad parameters given.
VOL │Volume label was displayed. │Drive not found or bad parameters given.
Tableau 3 - Commandes qui définissent ERRORLEVEL sur erreur; sinon, ne le changez pas
Command │E│ Set ERRORLEVEL to = when
─────────────┼─┼────────────────────────────────────────────────────────────────────────
ASSOC │*│1 = Extension associations could not be changed.
CLS │ │1 = Bad switch given.
DPATH │*│1 = Data path could not be established.
FTYPE │*│1 = File type associations could not be changed.
GOTO label │ │1 = Label not exist *in a subroutine* (equivalent to: EXIT /B 1).
KEYS │ │1 = Bad switch given.
PATH │*│1 = Path could not be changed.
POPD │ │1 = Bad switch given.
Prompt |*│1 = Prompt could not be changed.
SET var │*│1 = No variable with such name exists.
SET var=value│*│1 = Variable name start with "/" not enclosed in quotes.
SET /P │*│1 = Read an empty line or at end of file.
SET /A │*│1073750988 = Unbalanced parentheses, 1073750989 = Missing operand,
│ │1073750990 = Syntax error, 1073750991 = Invalid number,
│ │1073750992 = Number larger than 32-bits, 1073750993 = Division by zero.
SHIFT │ │1 = Bad switch given.
La colonne "E" du tableau 3 indique les commandes qui modifient leur comportement en fonction de l'état "Extensions" comme décrit dans la documentation correspondante. Lorsque les extensions sont activées (par défaut) et ces commandes sont placées dans un fichier avec .CMD extension au lieu de .BAT premièrement, ces commandes définissent SETERRORLEVEL = 0 lorsqu'elles se terminent sans erreur, c'est-à-dire lorsque les conditions décrites dans le tableau 3 sont pas présentes.
Tableau 4 - Cas particuliers
CALL Table1 │If the called command is anyone of Table 1 (excepting FOR and IF): set ERRORLEVEL = 0.
CALL subroutine │If the subroutine is called, not change prior ERRORLEVEL value;
│otherwise (subroutine not exists): set ERRORLEVEL = 1.
EXIT /B, EXIT │Not change prior ERRORLEVEL value.
EXIT /B number │Set ERRORLEVEL to given number.
EXIT number │Ends cmd.exe and set its returning ERRORLEVEL value to given number.
START command │If command is started, not change ERRORLEVEL; otherwise, set ERRORLEVEL = 9059.
START /WAIT bat |When the started Batch file end, set ERRORLEVEL = value from 'EXIT number' commmand.
notExist │If a non-existent command is entered for execution, set ERRORLEVEL = 9009.
VER │Set ERRORLEVEL = 0 almost always. If /? parameter is given, not change ERRORLEVEL.
Quittez la gestion du code
Il existe deux façons de tester la valeur ERRORLEVEL: via IF ERRORLEVEL / IF %ERRORLEVEL% ou en utilisant la commande command && thenCmd when ERRORLEVEL is 0 || elseCmd when ERRORLEVEL is not 0 construire. Cependant, certaines commandes et erreurs de redirection particulières renvoient une valeur qui ne fonctionne que dans le second cas et est pas reflétée dans ERRORLEVEL; nous pouvons appeler "Code de sortie" cette valeur. Lorsque ce code de sortie n'est pas nul, il peut être transmis au niveau ERREUR en exécutant n'importe quelle commande du tableau 1 dans la partie elseCmd. Vous pouvez lire plus de détails à ce sujet sur cet article .
Tableau 5 - Commandes ou fonctionnalités qui définissent le code de sortie
Feature │ Set Exit Code to = when
─────────────┼─────────────────────────────────────────────────────────────────────────
command │1 = Command not exist (when ERRORLEVEL = 9009).
redirection │1 = File not exists in "<", path not exists or access denied in ">" ">>".
drive: |1 = Drive unit not exists.
POPD |1 = No matching PUSHD was previously executed.
RD │1 = Bad switch given, 2 = Directory not found, 5 = Access denied,
│32 = Directory in use, 145 = Directory not empty.
FOR /F │1 = No data was processed.
Par exemple, pour tester si une erreur de redirection s'est produite, utilisez ceci:
command > C:\Path\that\does\not\exist\file.txt || rem
if errorlevel 1 echo Previous redirection failed
Dans cet exemple, la commande rem est utilisée pour copier le code de sortie dans ERRORLEVEL, mais toute autre commande interne qui conserve ERRORLEVEL peut être utilisée (à l'exception de FOR et IF) .
Pour tester si une unité d'entraînement existe:
U: || rem
if errorlevel 1 echo Previous set current drive to U: unit failed
Plus d'exemples:
rd c:\Some\directory 2> NUL || rem
if %errorlevel% equ 0 (
echo Directory deleted
) else if %errorlevel% equ 2 (
echo Directory not found
) else if %errorlevel% equ 5 (
echo Can not access the directory, check rights
) else if %errorlevel% equ 32 (
echo Can not delete current directory
) else if %errorlevel% equ 145 (
echo Directory is not empty, use /S switch
)
(for /F "options" %%a in (input.txt) do echo %%a) || rem
if errorlevel 1 echo Previous FOR didn't processed any value