Coller une plage Excel spécifique dans Outlook
Je travaille sur un rapport Excel que je souhaite automatiser, cependant, la plage des cellules n'est pas collée dans Outlook.
Voici mon code:
Sub Mail_Selection_Range_Outlook_Body()
Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Set rng = Nothing
On Error Resume Next
' Only send the visible cells in the selection.
Set rng = Selection.SpecialCells(xlCellTypeVisible)
Set rng = Sheets("Sheet1").RangeToHtml("D4:D12").SpecialCells(xlCellTypeVisible, xlTextValues)
On Error GoTo 0
If rng Is Nothing Then
MsgBox "The selection is not a range or the sheet is protected. " & _
vbNewLine & "Please correct and try again.", vbOKOnly
Exit Sub
End If
With Application
.EnableEvents = False
.ScreenUpdating = False
End With
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.To = ThisWorkbook.Sheets("Sheet2").Range("C1").Value
.CC = ""
.BCC = ""
.Subject = "This is the Subject line"
.HTMLBody = RangeToHtml.rng
' In place of the following statement, you can use ".Display" to
' display the e-mail message.
.Display
End With
On Error GoTo 0
With Application
.EnableEvents = True
.ScreenUpdating = True
End With
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
Je ne reçois aucune erreur, c'est juste qu'il ne colle pas de plage dans Outlook. Je vous remercie.
Tout d'abord, RangeToHTML. Le script l'appelle comme une méthode , mais ce n'est pas le cas. C'est une fonction populaire de MVP Ron de Bruin . Par coïncidence, ce lien pointe vers la source exacte du script que vous avez publié, avant que ces quelques lignes ne soient modifiées.
On avec Range.SpecialCells . Cette méthode fonctionne sur une plage et renvoie uniquement les cellules qui correspondent aux critères donnés. Dans votre cas, vous semblez uniquement intéressé par les cellules de texte visible . Surtout, il fonctionne sur une plage , pas sur du texte HTML.
Par souci d'exhaustivité, je publierai une version de travail du script ci-dessous. Je conseillerais certainement de ne pas en tenir compte et de revisiter l'excellent original de Ron the Bruin.
Sub Mail_Selection_Range_Outlook_Body()
Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Set rng = Nothing
' Only send the visible cells in the selection.
Set rng = Sheets("Sheet1").Range("D4:D12").SpecialCells(xlCellTypeVisible)
If rng Is Nothing Then
MsgBox "The selection is not a range or the sheet is protected. " & _
vbNewLine & "Please correct and try again.", vbOKOnly
Exit Sub
End If
With Application
.EnableEvents = False
.ScreenUpdating = False
End With
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
With OutMail
.To = ThisWorkbook.Sheets("Sheet2").Range("C1").Value
.CC = ""
.BCC = ""
.Subject = "This is the Subject line"
.HTMLBody = RangetoHTML(rng)
' In place of the following statement, you can use ".Display" to
' display the e-mail message.
.Display
End With
On Error GoTo 0
With Application
.EnableEvents = True
.ScreenUpdating = True
End With
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
Function RangetoHTML(rng As Range)
' By Ron de Bruin.
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.ReadAll
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function
Cette question est souvent posée dans le contexte de la fonction RangeToHTML de Ron de Bruin, qui crée un HTML PublishObject à partir d'un Excel.Range, L'extrait via FSO et insère le flux HTML résultant dans le HTMLBody de l'e-mail. Ce faisant, cela supprime la signature par défaut (la fonction RangeToHTML a une fonction d'assistance GetBoiler qui tente d'insérer la signature par défaut).
Malheureusement, la méthode Application.CommandBars Mal documentée n'est pas disponible via Outlook:
wdDoc.Application.CommandBars.ExecuteMso "PasteExcelTableSourceFormatting"
Il générera un runtime 6158:
Mais nous pouvons toujours tirer parti du Word.Document Qui est accessible via la méthode MailItem.GetInspector, Nous pouvons faire quelque chose comme ça pour copier et coller la sélection d'Excel dans le corps de l'e-mail Outlook, en préservant votre signature par défaut ( Si il y en a un).
Dim rng as Range
Set rng = Range("A1:F10") 'Modify as needed
With OutMail
.To = "[email protected]"
.BCC = ""
.Subject = "Subject"
.Display
Dim wdDoc As Object '## Word.Document
Dim wdRange As Object '## Word.Range
Set wdDoc = OutMail.GetInspector.WordEditor
Set wdRange = wdDoc.Range(0, 0)
wdRange.InsertAfter vbCrLf & vbCrLf
'Copy the range in-place
rng.Copy
wdRange.Paste
End With
Notez que dans certains cas, cela peut ne pas préserver parfaitement les largeurs de colonne ou dans certains cas les hauteurs de ligne, et bien qu'il copie également des formes et d'autres objets dans la plage Excel, cela peut également provoquer des problèmes d'alignement géniaux, mais pour les tableaux simples et Les gammes Excel, c'est très bien:
