web-dev-qa-db-fra.com

Comment obtenir une valeur DateDiff en millisecondes dans VBA (Excel)?

Je dois calculer la différence entre deux horodatages en millisecondes. Malheureusement, la fonction DateDiff de VBA n'offre pas cette précision. Existe-t-il des solutions de contournement?

excelvbaexcel-vbadatediff
19
Florian

Vous pouvez utiliser la méthode décrite ici comme suit: -

Créez un nouveau module de classe appelé StopWatch Placez le code suivant dans le module de classe StopWatch:

Private mlngStart As Long
Private Declare Function GetTickCount Lib "kernel32" () As Long

Public Sub StartTimer()
    mlngStart = GetTickCount
End Sub

Public Function EndTimer() As Long
    EndTimer = (GetTickCount - mlngStart)
End Function

Vous utilisez le code comme suit:

Dim sw as StopWatch
Set sw = New StopWatch
sw.StartTimer

' Do whatever you want to time here

Debug.Print "That took: " & sw.EndTimer & "milliseconds"

D'autres méthodes décrivent l'utilisation de la fonction VBA Timer, mais celle-ci n'est précise qu'au centième de seconde (centiseconde).

43
Adam Ralph

Si vous avez simplement besoin de temps en Centisecondes, vous n'avez pas besoin de l'API TickCount. Vous pouvez simplement utiliser la méthode VBA.Timer, présente dans tous les produits Office.

Public Sub TestHarness()
    Dim fTimeStart As Single
    Dim fTimeEnd As Single
    fTimeStart = Timer
    SomeProcedure
    fTimeEnd = Timer
    Debug.Print Format$((fTimeEnd - fTimeStart) * 100!, "0.00 "" Centiseconds Elapsed""")
End Sub

Public Sub SomeProcedure()
    Dim i As Long, r As Double
    For i = 0& To 10000000
        r = Rnd
    Next
End Sub
9
Oorang

GetTickCount et Performance Counter sont requis si vous souhaitez utiliser des microsecondes. 

'at the bigining of the module
Private Type SYSTEMTIME  
        wYear As Integer  
        wMonth As Integer  
        wDayOfWeek As Integer  
        wDay As Integer  
        wHour As Integer  
        wMinute As Integer  
        wSecond As Integer  
        wMilliseconds As Integer  
End Type  

Private Declare Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)  


'In the Function where you need find diff
Dim sSysTime As SYSTEMTIME
Dim iStartSec As Long, iCurrentSec As Long    

GetLocalTime sSysTime
iStartSec = CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'do your stuff spending few milliseconds
GetLocalTime sSysTime ' get the new time
iCurrentSec=CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'Different between iStartSec and iCurrentSec will give you diff in MilliSecs
1
Adarsha

Toutes mes excuses pour réveiller cet ancien post, mais j'ai eu une réponse:
Ecrivez une fonction pour Milliseconde comme ceci: 

Public Function TimeInMS() As String
TimeInMS = Strings.Format(Now, "HH:nn:ss") & "." & Strings.Right(Strings.Format(Timer, "#0.00"), 2) 
End Function

Utilisez cette fonction dans votre sous-marin: 

Sub DisplayMS()
On Error Resume Next
Cancel = True
Cells(Rows.Count, 2).End(xlUp).Offset(1) = TimeInMS()
End Sub
0
JayyM

Vous pouvez également utiliser la formule =NOW() calculée dans la cellule:

Dim ws As Worksheet
Set ws = Sheet1

 ws.Range("a1").formula = "=now()"
 ws.Range("a1").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 Application.Wait Now() + TimeSerial(0, 0, 1)
 ws.Range("a2").formula = "=now()"
 ws.Range("a2").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 ws.Range("a3").formula = "=a2-a1"
 ws.Range("a3").numberFormat = "h:mm:ss.000"
 var diff as double
 diff = ws.Range("a3")
0
ilya