web-dev-qa-db-fra.com

Classement des jours du mois les plus fréquents

J'aimerais savoir quels jours du mois les clients ont historiquement payé le plus. Je voudrais créer un rapport qui a les jours 1, 2, 3, 4 ... 31 avec un décompte à côté de chaque jour pour combien de fois il se produit dans notre colonne de date. J'aimerais aussi faire de même avec les jours de la semaine si possible. Toute aide serait grandement appréciée!

google-sheetsformulasgoogle-sheets-querygoogle-sheets-arrayformulagoogle-sheets-dates
1
George Young
=ARRAYFORMULA(QUERY(DAY(INDIRECT("A1:A"&COUNTA(A1:A))), 
 "select Col1,count(Col1) 
  group by Col1 
  label count(Col1)''", 0))

0

=ARRAYFORMULA({ROW(A1:A31), IFERROR(VLOOKUP(ROW(A1:A31), 
 QUERY(DAY(INDIRECT("A1:A"&COUNTA(A1:A))), 
 "select Col1,count(Col1) 
  group by Col1 
  label count(Col1)''", 0), 2, 0), 0)})

0

=ARRAYFORMULA({{"Mon";"Tue";"Wed";"Thu";"Fri";"Sat";"Sun"}, 
 IFERROR(VLOOKUP({"Mon";"Tue";"Wed";"Thu";"Fri";"Sat";"Sun"}, 
 QUERY(TEXT(INDIRECT("A1:A"&COUNTA(A1:A)), "ddd"), 
 "select Col1,count(Col1) 
  group by Col1 
  label count(Col1)''", 0), 2, 0), 0)})

0

démo de feuille de calcul

0
user0