web-dev-qa-db-fra.com

Calculer le nombre de dimanches du mois

Dans Microsoft Excel, je cherche à déterminer le nombre de dimanches au cours d’un mois donné. Je suis en train de préparer une feuille de calcul du budget et certains sous-comptes bénéficient d'un financement supplémentaire lorsque cinq dimanches ont lieu le mois au lieu de quatre.

La seule cellule à laquelle je dois faire référence est le titre de la feuille qui se trouve dans la cellule A1 et égale au mois en cours. Par exemple 6/1/14

microsoft-excelmicrosoft-excel-2010worksheet-functiondate-time
8
wbeard52

Essayez ceci où A1 est le jour de début du mois:

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))),"ddd")="Sun"))

Vous pouvez également l'utiliser pour n'importe quel jour de la semaine, il suffit de changer "Sun" et de toute plage de dates en remplaçant A1 par la date de début et EOMONTH(A1,0) par la date de fin.

12
Jay-ar

Si la date que vous mentionnez est toujours le premier du mois, celle-ci fonctionnera également:

=INT((WEEKDAY(A1-1)+EOMONTH(A1,0)-A1)/7)
9
teylyn

Très semblable à une réponse précédente, mais juste un peu plus propre ...

=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))))=1))
3
user743733
=DAY(EOMONTH(A1,0))-NETWORKDAYS.INTL(A1,EOMONTH(A1,0),11)

EDIT: Cela fonctionne dans Excel 2016, sans savoir quand NETWORKDAYS.INTL a été introduit.

2
SRCP

Je crois avoir trouvé un autre moyen de dépouiller ce chat (pour ainsi dire).

Si vous souhaitez éviter de saisir des dates et disposer d'une grande feuille pour la projection (18 mois par exemple), vous pouvez simplement indiquer à la formule les mois et l'année en question et la formater en conséquence. Cela rejoint une référence absolue à un en-tête de cellules qui contient le jour de la semaine en question et vous obtenez un tableau beaucoup plus compact et plus propre (à mon avis).

A3 = janvier, B3 = 2017, C2: I2 = abréviation du jour du car 3 (c.-à-d. Sun)

Entrez la formule dans la cellule C3

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy"))&":"&EOMONTH(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy")),0))),"ddd")=C$2))

Bonne chasse

1
Jeremy Cast

Une légère variation de réponse acceptée , où vous n'avez pas besoin du premier jour du mois dans A1.

Ceci est réalisé en remplaçant A1 par:

date(year(today()),month(today()),1)

Cela suppose que vous le voulez pour le mois en cours.

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(date(year(today()),month(today()),1)&":"&EOMONTH(date(year(today()),month(today()),1),0))),"ddd")="Sun"))
0
CalvT