web-dev-qa-db-fra.com

Oracle Rechercher dans toutes les tables toutes les colonnes pour la chaîne

J'ai besoin de rechercher dans notre base de données Oracle une chaîne dans toutes les tables et colonnes. J'ai la requête ci-dessous que j'ai trouvée en ligne mais quand je l'exécute j'obtiens l'erreur suivante

Toute aide est appréciée

ORA-06550: line 6, column 31:
PL/SQL: ORA-00904: "COLUMN_NAME": invalid identifier
ORA-06550: line 6, column 12:
PL/SQL: SQL Statement ignored
ORA-06550: line 8, column 30:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 7, column 4:
PL/SQL: Statement ignored
ORA-06550: line 12, column 38:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 12, column 16:
PL/SQL: Statement ignored

BEGIN  
  FOR t IN (SELECT table_name, column_name FROM all_tables) LOOP   
   EXECUTE IMMEDIATE    
    'SELECT COUNT(*) FROM '||t.table_name||' WHERE '||t.column_name||' = :1'   
     INTO match_count  
       USING v_search_string; 
          IF match_count > 0 THEN 
               dbms_output.put_line( t.table_name ||' '||t.column_name||' '||match_count );
           END IF; 
  END LOOP;
END;
/
oracleoracle11g
15
Jim

Au minimum, vous devez interroger ALL_TAB_COLUMNS, pas ALL_TABLES

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

Si vous recherchez une chaîne, cependant, vous voudrez certainement vous limiter à rechercher des colonnes pouvant stocker une chaîne. Il ne serait pas logique, par exemple, de rechercher une chaîne dans une colonne DATE. Et à moins que vous ayez beaucoup de connaissances a priori sur le contenu d'une colonne BLOB et la capacité d'analyser le formatage binaire de la colonne BLOB, il ne serait pas logique de rechercher une chaîne BLOB dans une colonne BLOB. Compte tenu de cela, je pense que vous voulez quelque chose de plus

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

Bien sûr, cela va être incroyablement lent - vous devez analyser chaque table une fois pour chaque colonne de chaîne de la table. Avec des tables modérément grandes et un nombre modéré de colonnes de chaînes, cela risque de prendre un certain temps.

32
Justin Cave