web-dev-qa-db-fra.com

Est-ce que xslt a une fonction split ()?

Comment diviser une chaîne en fonction d'un séparateur?

Étant donné la chaîne Topic1,Topic2,Topic3, je souhaite fractionner la chaîne en fonction de , pour générer:

Topic1 Topic2 Topic3
stringxsltsplit
24
Ketan

Dans XSLT 1.0, vous devez créer un modèle récursif. Cette feuille de style:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text/text()" name="tokenize">
        <xsl:param name="text" select="."/>
        <xsl:param name="separator" select="','"/>
        <xsl:choose>
            <xsl:when test="not(contains($text, $separator))">
                <item>
                    <xsl:value-of select="normalize-space($text)"/>
                </item>
            </xsl:when>
            <xsl:otherwise>
                <item>
                    <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
                </item>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Contribution:

<root>
<text>Item1, Item2, Item3</text>
</root>

Sortie:

<root>
    <text>
        <item>Item1</item>
        <item>Item2</item>
        <item>Item3</item>
    </text>
</root>

Dans XSLT 2.0, vous avez la fonction principale tokenize(). Donc, cette feuille de style:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text/text()" name="tokenize">
        <xsl:param name="separator" select="','"/>
        <xsl:for-each select="tokenize(.,$separator)">
                <item>
                    <xsl:value-of select="normalize-space(.)"/>
                </item>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Résultat:

<root>
    <text>
        <item>Item1</item>
        <item>Item2</item>
        <item>Item3</item>
    </text>
</root>
35
user357812

Utilisez fn:tokenize

3
Max Toro

Il n'y a pas de fonction split, mais vous pouvez utiliser un modèle récursif avec substring-before et substring-after pour écrire le vôtre.

Voir this article pour plus de détails.

2
Oded

Merci user357812. J'utilise votre modèle Nice avec peu de personnalisation pour le rendre générique:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <!-- Main template -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" mode="tokenize-children" />
        </xsl:copy>
    </xsl:template>

    <!-- Split child nodes -->
    <xsl:template match="*" mode="tokenize-children">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates select="*" mode="tokenize" />
        </xsl:copy>
    </xsl:template>

    <!-- Tokenize text node of child nodes -->
    <xsl:template match="*/text()" name="tokenize" mode="tokenize">
        <xsl:param name="text" select="."/>
        <xsl:param name="separator" select="','"/>
        <xsl:variable name="item"   select="name(..)" />
        <xsl:choose>
            <xsl:when test="not(contains($text, $separator))">
                <xsl:element name="{$item}">
                    <xsl:value-of select="normalize-space($text)"/>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:element name="{$item}">
                    <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
                </xsl:element>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>
1
Bludwarf

XSLT 1.0
J'avais besoin d'une variante légère par rapport aux autres réponses données ici. 

Contribution:

1, 2, 3

Résultat:

1, 2 et 3

Contribution:

1

Sortie

1

Si le délimiteur est un espace au lieu d'une virgule, cela fonctionnerait quand même.

Contribution:

1 2 3

Résultat:

1, 2 et 3

Je viens de créer un modèle légèrement modifié.

<xsl:template name="tokenizeString">
<xsl:param name="list"/>
<xsl:param name="delimiter"/>
<xsl:choose>
    <xsl:when test="contains($list, $delimiter)">      
        <xsl:variable name="listLength" select="string-length($list)" />
        <xsl:variable name="listLengthWithoutDelimiters" select="string-length(translate($list, $delimiter,''))" />
        <xsl:variable name="noOfDelimiters" select="($listLength - $listLengthWithoutDelimiters)" />

        <xsl:value-of select="substring-before($list,$delimiter)"/>
        <xsl:if test="$noOfDelimiters > 1">, </xsl:if>
        <xsl:if test="$noOfDelimiters = 1"> and </xsl:if>
        <xsl:call-template name="tokenizeString">
            <xsl:with-param name="list" select="substring-after($list,$delimiter)"/>
            <xsl:with-param name="delimiter" select="$delimiter"/>
        </xsl:call-template>
    </xsl:when>
     <xsl:otherwise>
        <xsl:choose>
            <xsl:when test="$list = ''">
                <xsl:text/>
            </xsl:when>
            <xsl:otherwise>
                 <xsl:value-of select="$list"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:otherwise>
</xsl:choose>

Le modèle peut être appelé comme ci-dessous lorsque le délimiteur est une virgule

<xsl:call-template name="tokenizeString">
    <xsl:with-param name="list">1, 2, 3</xsl:with-param>
    <xsl:with-param name="delimiter">
        <xsl:value-of select="','" />
    </xsl:with-param>
</xsl:call-template>

Le modèle peut être appelé comme ci-dessous lorsque le délimiteur est espace

<xsl:call-template name="tokenizeString">
    <xsl:with-param name="list">1 2 3</xsl:with-param>
    <xsl:with-param name="delimiter">
        <xsl:value-of select="' '" />
    </xsl:with-param>
</xsl:call-template>
1
ksoni

Selon le processeur XSL que vous utilisez, vous pouvez avoir accès à la fonction d’extension str: tokenize () .

Donc, diviser Topic1,Topic2,Topic3 sur , do;

<xsl:copy-of select="str:tokenize('Topic1,Topic2,Topic3', ',')"/>

qui donnera le résultat;

<token>Topic1</token>
<token>Topic2</token>
<token>Topic3</token>
0
Nigel Alderton