Créer un dossier .Zip à partir de la ligne de commande - (Windows)
Est-il possible de créer un fichier .Zip à partir d'un dossier en ligne de commande, je ne souhaite utiliser aucun exécutable tiers.
Je pensais quelque chose comme 'envoyer dans un dossier compressé' mais je ne sais pas comment le faire ...
À partir de PowerShell 5 (février 2016), vous pouvez utiliser "Compress-Archive":
Compress-Archive -Path input.txt -DestinationPath output.Zip
Ou:
Compress-Archive input.txt output.Zip
http://msdn.Microsoft.com/powershell/reference/5.0/Microsoft.powershell.archive/compress-archive
Je ne pense pas qu'il existe une ligne de commande pour les fichiers Zip intégrés à Windows (autre que compress dans le Kit de ressources Server 2003). Vous devrez utiliser un tiers. Tout le monde aime 7Zip !
J'ai combiné ce script de plusieurs sources différentes pour mieux répondre à mes besoins. Copiez et collez le script dans un fichier avec l'extension ".vbs". Le script a été conçu à l'origine pour Windows XP, mais il fonctionne également sous Windows 7 x64 Ultimate - rien ne garantit que Windows conservera les différents objets Shell utilisés.
Utilisation: dans la boîte d'exécution ou la ligne de commande
"C:\zipper.vbs" "C:\folderToZip\" "C:\mynewzip.Zip"
Chemin du script, dossier source, fichier Zip à créer (inclure le .Zip à la fin).
Il ne copiera pas les dossiers vides alors soyez prudent.
Voici le code vbs ---
Set Args = Wscript.Arguments
source = Args(0)
target = Args(1)
' make sure source folder has \ at end
If Right(source, 1) <> "\" Then
source = source & "\"
End If
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set Zip = objFSO.OpenTextFile(target, 2, vbtrue)
' this is the header to designate a file as a Zip
zip.Write "PK" & Chr(5) & Chr(6) & String( 18, Chr(0) )
Zip.Close
Set Zip = nothing
wscript.sleep 500
Set objApp = CreateObject( "Shell.Application" )
intSkipped = 0
' Loop over items within folder and use CopyHere to put them into the Zip folder
For Each objItem in objApp.NameSpace( source ).Items
If objItem.IsFolder Then
Set objFolder = objFSO.GetFolder( objItem.Path )
' if this folder is empty, then skip it as it can't compress empty folders
If objFolder.Files.Count + objFolder.SubFolders.Count = 0 Then
intSkipped = intSkipped + 1
Else
objApp.NameSpace( target ).CopyHere objItem
End If
Else
objApp.NameSpace( target ).CopyHere objItem
End If
Next
intSrcItems = objApp.NameSpace( source ).Items.Count
wscript.sleep 250
' delay until at least items at the top level are available
Do Until objApp.NameSpace( target ).Items.Count + intSkipped = intSrcItems
wscript.sleep 200
Loop
'cleanup
Set objItem = nothing
Set objFolder = nothing
Set objApp = nothing
Set objFSO = nothing
Voici une autre idée, provenant de 4 sources différentes; pas mes idées, mais je les ai compilées pour que cela fonctionne pour moi
<!-- : Begin batch script
@each off
set sourceFolder="c:\test"
set destZip="%userprofile%\desktop\example.Zip"
cscript //nologo "%~f0?.wsf" //job:exewsh %sourceFolder% %destZip%
exit /b
GOTO:EOF
----- Begin wsf script --->
<package><job id="exewsh"><script language="VBScript">
'Get command-line arguments.
Set objArgs = WScript.Arguments
InputFolder = objArgs(0)
ZipFile = objArgs(1)
'Create empty Zip file.
CreateObject("Scripting.FileSystemObject").CreateTextFile(ZipFile, True).Write "PK" & Chr(5) & Chr(6) & String(18, vbNullChar)
Set objShell = CreateObject("Shell.Application")
Set source = objShell.NameSpace(InputFolder).Items
objShell.NameSpace(ZipFile).CopyHere(source)
'Required!
wScript.Sleep 2000
</script></job>
</package>
Voici un excellent lien qui montre comment compresser un fichier à l’aide de commandes natives Windows.
Je l'ai testé avec un répertoire contenant plusieurs fichiers et dossiers imbriqués et cela a parfaitement fonctionné. Suivez simplement le format de la ligne de commande.
Il existe également un moyen de décompresser les fichiers via une ligne de commande que j'ai également trouvée. Une solution consiste à ouvrir une fenêtre de l’explorateur indiquant le contenu du fichier compressé. Certains d'entre eux utilisent également Java qui n'est pas nécessairement natif de Windows mais qui est si commun qu'il semble presque l'être.
Windows 7 possède-t-il unzip sur la ligne de commande installé par défaut?
https://stackoverflow.com/questions/1021557/how-to-unzip-a-file-using-the-command-line
Imaginez que vous vouliez compresser le même dossier que celui sur lequel vous vous trouvez sans invite, en ouvrant une fenêtre PowerShell:
powershell Compress-Archive . publish.Zip
Il est possible d'exécuter le script PowerShell à partir de BAT. Le fichier de batte reçoit le chemin du répertoire à compresser et le nom du fichier Zip en tant que paramètres.
@echo off
setlocal
rem First parameter - path to dir to be zipped
rem Second parameter- Zip file name
set sourceDir=%1
set zipFile=%2
rem Create PowerShell script
echo Write-Output 'Custom PowerShell profile in effect!' > %~dp0TempZipScript.ps1
echo Add-Type -A System.IO.Compression.FileSystem >> %~dp0TempZipScript.ps1
echo [IO.Compression.ZipFile]::CreateFromDirectory('%sourceDir%','%~dp0%zipFile%') >> %~dp0TempZipScript.ps1
rem Execute script with flag "-ExecutionPolicy Bypass" to get around ExecutionPolicy
PowerShell.exe -ExecutionPolicy Bypass -Command "& '%~dp0TempZipScript.ps1'"
del %~dp0TempZipScript.ps1
endlocal
C'est une vieille question, mais sa pertinence est toujours d'actualité.
Bien sûr, Windows a son propre algorithme de compression intégré pour l’utilisation de fichiers Zip, mais ses performances sont médiocres par rapport au produit open source 7Zip présenté ici http://www.7-Zip.org/
D'autres ont déjà évoqué diverses méthodes d'utilisation des fonctions Windows intégrées. Ma solution nécessite l'installation du logiciel supplémentaire.
7Zip prend en charge une large gamme de fichiers, notamment Zip, RAR, CAB et ISO, ainsi que son propre format 7z.
Vous pouvez afficher l'aide en ligne de commande: "C:\Program Files\7-Zip\7z.exe" --help
effectuer une simple addition à l'archive Zip:
"C:\Program Files\7-Zip\7z.exe" un nom de fichier.Zip c:\chemin
Je vais poster quelque chose lié à WSkids répondre aussi malheureusement que je ne peux pas utiliser la fonction de commentaire.
L'utilisation de la méthode CopyHere () dans VBS soulève plusieurs problèmes. L'un de ces problèmes est que la méthode retourne immédiatement pendant que le processus de copie démarre en arrière-plan, alors que plusieurs appels à CopyHere () s'interféreront et que le zip ne sera pas créé correctement. Une boucle d'attente est nécessaire ici pour résoudre ce problème. Ma boucle d'attente est basée sur une réponse à un problème similaire posté ici .
Voici une version mise à jour qui corrige l'erreur "Object required" signalée par pihentagy . C'est un problème de synchronisation car le fichier Zip nouvellement créé est inclus dans la collection Items lorsque le script est exécuté sur des machines rapides.
set Args = WScript.Arguments
source = Args(0)
' remove trailing slashes as we add slashes when needed later
while Right(source, 1) = "\"
source = Mid(source, 1, Len(source) - 1)
wend
target = Args(1)
' create empty Zip file
set fso = CreateObject("Scripting.FileSystemObject")
set Zip = fso.OpenTextFile(target, 2, vbtrue)
' write Zip header, this ensures that Windows recognizes the file as "Zip Folder"
Zip.Write "PK" & Chr(5) & Chr(6) & String(18, Chr(0))
Zip.Close
set Zip = nothing
set fso = nothing
' copy files to Zip file
set app = CreateObject("Shell.Application")
set sourceFolderObj = app.NameSpace(source)
set targetFolderObj = app.NameSpace(target)
for each item in sourceFolderObj.Items
itemPath = source & "\" & item.Name
copyItem = false
' Zip file is included in Items collection and is recognized as folder, thus skip it to avoid script errors
if itemPath <> target then
if item.IsFolder then
if item.GetFolder.Items().Count = 0 then
' folder is empty, skip it as empty folders can't be compressed
else
copyItem = true
end if
else
copyItem = true
end if
end if
if copyItem then
targetFolderObj.CopyHere item
' wait until the file appears in the Zip file,
' this is needed because CopyHere() returns immediately after starting an asynchronous copy process
' (starting multiple asynchronous copy will not work as it causes error messages, an invalid Zip file, ...)
while (targetFolderObj.ParseName(item.Name) is nothing)
WScript.Sleep 1
wend
end If
next
set targetFolderObj = nothing
set sourceFolderObj = nothing
set app = nothing
Voici ma tentative de synthèse des fenêtres de fonctionnalités intégrées pour la compression et la décompression - https://stackoverflow.com/questions/28043589/how-can-i-compres-Zip-and-uncopress-unzip-files-and -folders-with-batch-f
avec quelques solutions données qui devraient fonctionner sur presque toutes les machines Windows.