Un fichier de commandes Windows peut-il déterminer son propre nom de fichier?
Un fichier de commandes Windows peut-il déterminer son propre nom de fichier?
Par exemple, si j'exécute le fichier de commandes C:\Temp\myScript.bat, existe-t-il une commande dans myScript.bat permettant de déterminer la chaîne "myScript.bat"?
Oui.
Utilisez la variable spéciale %0 pour obtenir le chemin du fichier actuel.
Écrivez %~n0 pour obtenir uniquement le nom de fichier sans l'extension.
Écrivez %~n0%~x0 pour obtenir le nom de fichier et l'extension.
Également possible d'écrire %~nx0 pour obtenir le nom de fichier et l'extension.
Vous pouvez obtenir le nom du fichier, mais vous pouvez également obtenir le chemin complet, en fonction de ce que vous placez entre '% ~' et '0'. Faites votre choix parmi
d -- drive
p -- path
n -- file name
x -- extension
f -- full path
Par exemple, à l'intérieur de c:\tmp\foo.bat, %~nx0 vous donne "foo.bat", alors que %~dpnx0 donne "c:\tmp\foo.bat". Notez que les pièces sont toujours assemblées dans un ordre canonique, donc si vous devenez mignon et essayez %~xnpd0, vous encore obtenez "c:\tmp\foo.bat"
En utilisant le script suivant, basé sur la réponse SLaks, j'ai déterminé que la réponse correcte était:
echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0
Et voici mon script de test:
@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause
Ce que je trouve intéressant, c'est que% nx0 ne fonctionnera pas, étant donné que nous savons que le caractère '~' est généralement utilisé pour effacer/couper les guillemets d'une variable.
Gardez à l'esprit que 0 est un cas particulier de numéro de paramètre dans un fichier batch, où 0 signifie que ce fichier est indiqué sur la ligne de commande.
Ainsi, si le fichier est myfile.bat, vous pouvez l'appeler de différentes manières, chacune d'elles vous donnant une sortie différente à partir de l'utilisation de% 0 ou% ~ 0:
mon fichier
monfichier.bat
mondir\monfichier.bat
c:\mydir\myfile.bat
"c:\mydir\myfile.bat"
Tous les appels ci-dessus sont des appels légaux si vous l'appelez de l'emplacement relatif correct vers le répertoire dans lequel ils existent. % ~ 0 supprime les guillemets du dernier exemple, contrairement à% 0.
Comme ils donnent tous des résultats différents, il est très peu probable que% 0 et% ~ 0 correspondent à ce que vous voulez réellement utiliser.
Voici un fichier batch pour illustrer:
@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause
Essayez d’exécuter l’exemple ci-dessous afin de comprendre le fonctionnement des variables magiques.
@echo off
SETLOCAL EnableDelayedExpansion
echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with extension: %~nx0
echo Extension: %~x0
echo date time : %~t0
echo file size: %~z0
ENDLOCAL
Les règles connexes suivent.
%~I - expands %I removing any surrounding quotes ("")
%~fI - expands %I to a fully qualified path name
%~dI - expands %I to a drive letter only
%~pI - expands %I to a path only
%~nI - expands %I to a file name only
%~xI - expands %I to a file extension only
%~sI - expanded path contains short names only
%~aI - expands %I to file attributes of file
%~tI - expands %I to date/time of file
%~zI - expands %I to size of file
%~$PATH:I - searches the directories listed in the PATH
environment variable and expands %I to the
fully qualified name of the first one found.
If the environment variable name is not
defined or the file is not found by the
search, then this modifier expands to the
empty string
Ci-dessous mon code initial:
@echo off
Set z=%%
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.
J'ai remarqué que le nom de fichier donné par% ~ 0 et% 0 correspond à la manière dont il a été entré dans la commande-shell et non à la manière dont ce fichier est nommé. Donc, si vous voulez utiliser la casse littérale pour le nom du fichier, utilisez% ~ n0. Cependant, cela laissera l'extension du fichier. Mais si vous connaissez le nom du fichier, vous pouvez ajouter le code suivant.
set b=%~0
echo %~n0%b:~8,4%
J'ai appris que ": ~ 8,4%" signifie commencer au 9ème caractère de la variable et ensuite afficher les 4 caractères suivants. La plage est comprise entre 0 et la fin de la chaîne de variable. Donc,% Path% serait très long!
fIlEnAmE.bat
012345678901
Cependant, cela n’est pas aussi solide que la solution de Jool (% ~ x0) ci-dessus.
Mes preuves:
C:\bin>filename.bat
%0.......filename.bat
%~0......filename.bat
. . .
C:\bin>fIlEnAmE.bat
%0.......fIlEnAmE.bat
%~0......fIlEnAmE.bat
%n0......n0
%x0......x0
%~n0.....FileName
%dp0.....dp0
%~dp0....C:\bin\
%~n0%b:~8,4%...FileName.bat
Press any key to continue . . .
C:\bin>dir
Volume in drive C has no label.
Volume Serial Number is CE18-5BD0
Directory of C:\bin
. . .
05/02/2018 11:22 PM 208 FileName.bat
Voici le code final
@echo off
Set z=%%
set b=%~0
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.
echo A complex solution:
echo ===================================
echo %z%~n0%z%b:~8,4%z%...%~n0%b:~8,4%
echo ===================================
echo.
echo The preferred solution:
echo ===================================
echo %z%~n0%z%~x0.......%~n0%~x0
echo ===================================
pause